시리얼 통신제어 방법

1. 시리얼 통신이란?

"시리얼 통신"이란 일반적으로 컴퓨터 기기를 접속하는 방법의 하나로, 접속하는 선의 수를 삭감하고, 또한 원거리까지 신호를 보낼 수 있도록 한 방식을 말한다. 이때 신호가 1비트마다 시리얼(직렬)로 보내지기 때문에 시리얼 통신이라 부른다.


2. 퍼스널컴퓨터와의 접속

여기서는 통신 접속 상대방을 퍼스널컴퓨터로 한다. 그러나, 이 시리얼 통신의 접속은 표준화되어 있으며, "RS-232C"라 부르고 있는데, 대부분의 퍼스널컴퓨터나 모뎀이 이 규격에 따르고 있기 때문에 같은 방법으로 접속할 수 있다.
이 접속에는 "25핀 DSUB 커넥터"나 "9핀 미니 DSUB 커넥터"라 부르는 커넥터가 일반적으로 사용되고 있으므로, 그것을 전제로 설명한다.
커넥터의 핀 번호와 신호 및 간이적인 사용법은 아래 표와 같다.

미니DSUB
커넥터

25핀
DSUB

신호 명칭

간단한 사용법

1

8

CD(Data Carrier Detect)

입력, 사용하지 않는다

2

3

RD(Receive Data)

입력, 상대방 TD에 접속

3

2

TD(Transmit Data)

출력, 상대방 RD에 접속

4

20

DTR(Data Terminal Ready)

출력, 사용하지 않는다

5

7

SG(Signal Ground)

그라운드, 상대방 SG에 접속

6

6

DSR(Data Set Ready)

입력, 사용하지 않는다

7

4

RTS(Request to Send)

출력, 상대방 CTS와 접속

8

5

CTS(Clear to Send)

입력, 상대방 RTS와 접속

9

22

RI(Ring Indicate)

입력, 사용하지 않는다

 

3. 시리얼 통신 제어 프로그램의 구성

여기서 소개하는 통신용 프로그램은 타이머 인터럽트를 사용하고 있다. 이 인터럽트를 사용함으로써 각 비트의 신호를 기다리고 있는 동안, 컴퓨터에는 다른 작업을 시킬 수 있다. 따라서, 통신을 하면서 다른 일을 하려는 경우, 예를 들면 표시를 하거나 모터를 동작시키는 일이 가능해진다.
전체는 3개의 프로그램 모듈과 하나의 변수 정의 부분으로 구성되어 있다.

    (1) 변수 정의 부분
    통신 프로그램에서 사용하는 변수나 정수를 정의하고 있다. 여기서 중요한 것은 통신속도를 변경하기 위한 파라미터이다. 속도를 바꾸기 위해서는 2개의 파라미터의 값을 변경하고 어셈블하여 고친다.

    (2) 인터럽트 처리 모듈(INTERRUPT)
    이것은 인터럽트가 들어왔을 때, 그때의 레지스터를 보존한 후, 각 플래그를 보고 어떤 상태의 인터럽트인지를 판정하고 필요한 처리로 점프한다. 또한 각 처리가 종료된 후 인터럽트가 들어간 곳으로 돌아가기 위해 보존해 둔 레지스터를 원래대로 되돌려 리턴한다.

    (3) 송신 프로그램 모듈(PUTCHAR)
    송신은 비교적 단순하며, 송신 요구가 있으면 우선 start bit을 출력하여 일정시간의 타이머를 스타트시킨다. 타이머의 인터럽트가 들어왔으면 순차 데이터를 1비트씩 시프트하면서 출력한다.
    마지막으로 stop bit를 송신하여 완료한다.

    (4) 수신 프로그램 모듈(GETCHAR)
    수신 처리의 부분에서, 우선 스타트 펄스를 수신할 수 있도록 타이머를 풀카운트에서 하나 적은 상태로 설정해 둔다.
    그래서 스타트 비트에 의해 +1 카운트하면 인터럽트가 발생하고, 스타트 비트의 검출을 할 수 있게 된다. 다음은 일정시간마다 타이머 인터럽트가 발생하도록 하여 그 때마다 데이터를 입력한다.
    이것을 그림으로 나타내면 아랫 그림과 같이 된다.


여기서 약간 연구되어 있는 것은 우선 스타트 비트의 인터럽트가 들어왔다면, 확인하기 위해 10μs 기다린 다음, 다시 한번 입력을 읽어들여 보고, 같은 신호였다면 스타트 비트로 간주한다.
다르면 노이즈로 인터럽트가 들어온 것으로 간주하여 무시하고, 다음 스타트 비트의 인터럽트를 기다린다.
확실히 스타트 비트를 받아들였다면 다음의 타이머는 1.5비트분의 시간으로 스타트한다.
그리고 time up의 인터럽트가 들어오면 데이터로 입력을 읽어들인다. 이것으로 틀림없이 확실한 데이터를 읽어들이게 된다. 이하, 1비트분 시간의 타이머로 계속한다.

 

 

 

4. 변수, 정수의 정의

(1) 통신속도용 파라미터
통신속도를 가변으로 하기 위해 2개의 파라미터를 사용하고 있다. 그 값을 구하는 방법은 아래와 같이 한다.
우선, 통신속도로부터 1비트의 펄스폭을 구한다. 다음에 마이크로컴퓨터의 클록으로 그것을 나누어 카운터의 값을 구한다(1카운트는 4클록분). 그리고 그 카운트값을 실현하는 prescaler와 TMR0의 값을 구한다.
아래 표는 실제의 예이며, 클록은 10MHz의 경우이다.


BaudRate

PulseWidth

Counter

prescale

TMR0(BITTMR)

width

300bps

3333.33usec

8333

64(5)

130(7E)

3328usec

1200

833.33

2083

16(3)

130(7E)

832

2400

416.67

1041

8(2)

128(80)

409

4800

208.33

521

4(1)

124(84)

198

9600

104.17

260

2(0)

122(86)

99

 

여기서 4800, 9600bps의 경우에는 프로그램의 실행시간에 의한 지연분을 공제한 값으로 되어 있다(약 6μs분).
또한 상기 prescale의 괄호속의 값이 프리스케일러 설정용의 값으로 되며, 이것을 BAUDRATE의 값으로 설정한다.

프로그램 리스트상은 아래와 같이 되어 있다.

 


 

;
;BAUDRATE: boud rate 300 to 9600 at 10MHz clock.
;  5=300bps  3=1200bps  2=2400bps  1=4800bps  0=9600bps
;
BAUDRATE  SET    0        ;여기에 프리스케일러값을 지정한다
BITTMR       SET    086H   ;TMR0에 설정하는 값으로 위의 표에 나타낸 값을 지정한다
BITTMR1     SET    050H    ;스타트 비트일 때의 약 1.5비트분의 값

 

 

(2) 기타 변수
기타 범용으로 사용하는 변수와, 플래그류는 다음과 같이 정의되어 있다.


 

;*************************************
; Define constant module
;*************************************
#DEFINE     TXBUSY      RESULT,0     ;sending
#DEFINE     RXBUSY      RESULT,2     ;receiving
#DEFINE     RECV          RESULT,3     ;receive end
#DEFINE     ERROR        RESULT,4     ;error bit

;**** Define Variables *****
RESULT      EQU           0CH              ;current status
WREG         EQU           0DH              ;wreg save area
SREG          EQU           0EH              ;status reg save area
BITCNT       EQU           0FH               ;send bit counter
EXTRA        EQU           10H               ;stop bit flag
TXREG        EQU           11H              ;send data buffer
RXREG       EQU           12H               ;receive data buffer
CNT2          EQU           13H               ;counter for delay


5. 인터럽트 처리 프로그램

인터럽트가 들어갔을 때에 우선 실행하는 처리이다. 여기서는 레지스터의 대피, 복구와 각종 플래그를 보고 어떤 인터럽트인지를 판정하여 각각의 처리로 분기한다.
이 처리의 리스트는 다음과 같다.

 

;****************************************
; Interrupt process module
;****************************************
INTERRUPT                                     ;4번지에서 여기로 점프한다
                 BTFSS      INTCON,T0IF   ;TMR0의 인터럽트인지 확인
RETFIE                                            ;다르면 아무 일도 하지 않고 리턴한다
BCF           INTCON,T0IF                   ;TMR0의 인터럽트 플래그 클리어

;**** W register & status register를 대피
                 MOVWF    WREG             ;W reg를 대피
                 SWAPF     STATUS,W       ;status를 wreg에 이동
                 MOVWF    SREG              ;status를 대피
                 BTFSC      TXBUSY          ;송신중인가?
                 GOTO       TXNEXT          ;송신중이라면 다음 비트 송신으로
                 BTFSC      RXBUSY          ;수신중인가?
                 GOTO       RXNEXT          ;수신중이라면 다음 비트 수신으로
                 GOTO       STARTBIT         ;스타트 비트 인터럽트 처리로

;**** register를 복귀시켜 인터럽트가 들어간 장소로 돌아간다
RESTORE   SWAPF     SREG,W           ;status 꺼냄
                 MOVWF    STATUS            ;status 복귀
                 SWAPF     WREG,F            ;wreg 꺼냄
                 SWAPF     WREG,W           ;wreg 복귀
                 RETFIE                             ;다음 인터럽트 허가 리턴


6. 송신 처리 프로그램

송신은 타이머로 일정시간마다 인터럽트를 내고, 그 때마다 송신 데이터의 비트를 순차 송출한다. 송출하는 곳은 항상 RA3의 포트이다.
아래 리스트로 설명한다.

  1. 우선, 송신 요구가 CALL되면 PUTCHAR 처리로 TXBUSY 플래그를 세트하여 송신중으로 하며, 계속해서 스타트 비트를 송신하여 타이머를 1비트분의 시간에 세트한 다음, 스타트시키고나서 인터럽트 대기로 한다(TXSTART).
  2. 타이머가 count up하여 끼어들면 TXNEXT 처리로 분기하여 데이터의 송신을 1비트마다 한다. 그 비트마다 타이머를 세트하여 인터럽트를 기다린다.
  3. 최후의 데이터 송신후에는 stop bit의 송신(STOPBIT)으로 분기하여 1비트분의 스톱비트를 출력한다.
  4. 다음 인터럽트로 모두 종료하고 DONE로 분기하여 인터럽트를 금지로 하고 종료한다.

;************************************
; Transmission process module
;************************************
;송신 개시 처리
PUTCHAR
               BSF          TXBUSY               ;송신중 플래그를 세트
               MOVLW    8                          ;송신 데이터 비트수를 8로 하고
               MOVWF    BITCNT                 ;비트 카운터에 세트
               MOVLW    1                          ;스톱비트수를 1로 하고
               MOVWF    EXTRA                  ;카운터에 세트
               CALL        TXSTART              ;스타트 비트 송신
               BCF          INTCON,T0IF         ;인터럽트 플래그 클리어
               BSF          INTCON,T0IE         ;타이머 인터럽트 허가
               RETFIE
;**** 스타트 비트 송신처리 ****
TXSTART
               CLRF        TMR0                    ;타이머 세트
               BSF          STATUS,RP0          ;page 1
               CLRWDT
               MOVLW     BAUDRATE            ;프리스케일러 세트
               MOVWF     OPTION_REG
               BCF           STATUS,RP0         ;page 0
               BCF           PORTA,3               ;스타트 비트 세트
               MOVLW     BITTMR                 ;타이머값 꺼냄
               MOVWF     TMR0                    ;타이머 스타트
               RETURN
;****** 데이터 비트의 송신처리 *****
TXNEXT
               MOVLW      BITTMR                 ;타이머 재 스타트
               MOVWF      TMR0
               MOVF         BITCNT                 ;전체 비트 종료인가?
               BTFSC        STATUS,Z
               GOTO         STOPBIT               ;종료시 스톱비트 송신으로
NEXTTXBIT
               DECF          BITCNT,F              ;비트 카운터-1
               BSF            STATUS,C             ;데이터 비트를 시프트
               RRF            TXREG                  ;
               BTFSS        STATUS,C             ;데이터 비트의 0, 1에 의해
                                                             ;RA3에 0, 1을 출력
               BCF            PORTA,3               ;0 out
               BTFSC        STATUS,C
               BSF            PORTA,3                ;1 out
               GOTO         RESTORE               ;return
;**** 스톱비트 송신처리 ****
STOPBIT
               MOVF         EXTRA,W                ;스톱비트 송신이 끝났는가?
               BTFSC        STATUS,Z               ;
               GOTO         DONE                     ;송신끝 종료로
               DECF          EXTRA,F                 ;스톱비트 카운터-1
               BSF            PORTA,3                 ;스톱비트 출력
               GOTO         RESTORE                ;return
;*** 전체 데이터 송신완료, 종료처리 ****
DONE
               BCF            INTCON,T0IE            ;타이머 인터럽트 금지
               BCF            TXBUSY                  ;송신중 플래그 클리어
               GOTO         RESTORE                ;return

 

 

 7. 수신 처리 프로그램

수신은 약간 처리 내용이 복잡하지만, 흐름은 단순하다.

  1. 먼저 수신 요구가 있으면 GETCHAR로 스타트 비트의 수신준비 처리를 실행한다. 이것에는 타이머를 풀카운트 하나 바로 전에 인터럽트 대기로 한다.
  2. 스타트 비트 입력에 의해 타이머의 인터럽트가 들어가면 STARTBIT로 분기하여 10μs 기다린 후, 다시 한번 데이터를 입력하여 스타트 비트임을 확인한다.
    만일 그렇지 않았다면 노이즈에 의한 오류 인터럽트로 간주하고 아무것도 하지 않으며, 다음 스타트 비트 대기로 하고 리턴한다(NOISE). 확실히 스타트 비트였다면 수신중 플래그(RXBUSY)를 세트하고, 타이머에 1.5비트폭분의 타이머값을 세트하며 인터럽트 대기로 한다.
  3. 다음부터의 인터럽트는 데이터 비트로서 데이터 수신(RXNEXT)으로 분기한다.
    여기서는 1비트분 폭의 시간에 타이머를 리턴하고 순차 데이터 비트의 수신으로 RXREG에 저장해 간다(NEXTRXBIT). 최후의 데이터 비트의 다음은 stop bit의 수신일 것이므로 그것을 확인한다. 만일 스톱비트가 아니면 오류로 ERROR 플래그를 세트하고 종료한다. 종료시에는 수신중 플래그(RXBUY)를 클리어한다. 또한 정상으로 데이터를 수신할 수 있었을 때에는 데이터 수신 플래그(RECV)를 세트한다.

  1.  

     

;*************************************
; Receiving process module
;*************************************
GETCHAR
              BSF             RECV                ;데이터 수신 플래그 클리어
              MOVLW       9                       ;데이터 비트수를 8로하고
              MOVWF       BITCNT              ;비트 카운터에 세트
              CLRF           RXREG              ;데이터 버퍼 클리어
              BCF             ERROR              ;에러 플래그 클리어
;**** 스타트 비트 수신 준비처리 ****
              CLRF           TMR0                 ;타이머를 초기 세트
              BSF             STATUS,RP0       ;page 1
              CLRWDT                               ;clear WDT
              MOVLW       038H                   ;watchdog timer 모드
              MOVWF       OPTION_REG      ;로 prescaler를 1로 세트
              BCF             STATUS,RP0       ;page 0
              MOVLW       OFFH                  ;타이머를 FF로 세트
              MOVWF       TMR0                  ;타이머 스타트
              BCF             INTCON,T0IF        ;타이머 인터럽트 플래그 클리어
              BSF             INTCON,T0IE        ;타이머 인터럽트 허가
              RETFIE                                   ;인터럽트 대기로

;**** 스타트 비트 인터럽트 처리 ****
STARTBIT
              CLRWDT                                 ;
              CALL           TIME10                 ;10μs 대기
              BTFSC         PORTA,4              ;재 읽기 스타트 비트인가?
              GOTO          NOISE                  ;다를 때
              BSF             RXBUSY               ;수신중 플래그 ON
;데이터 수신준비
              CLRF           TMR0                    ;타이머 재차 세트
              BSF             STATUS,RP0         ;page 1
              MOVLW       BAUDRATE            ;프리스케일러 세트
              MOVWF       OPTION_REG
              BCF             STATUS,RP0          ;page 0
              MOVLW       BITTMR1                ;1.5비트폭의 시간으로 세트
              MOVWF       TMR0                     ;타이머 스타트
              GOTO          RESTORE               ;return
;*** 스타트 비트가 아닐 때의 처리 ****
NOISE
              MOVLW       OFFH                     ;타이머 재차 세트
              MOVWF       TMR0
              GOTO          RESTORE               ;return
;**** 데이터 비트 수신처리 ****
RXNEXT
              BSF             STATUS,RP0            ;page 1
              CLRWDT                                     ;타이머 재차 세트
              MOVLW        BAUDRATE
              MOVWF        OPTION_REG
              BCF              STATUS, RP0          ;page 0
              MOVLW        BITTMR                   ;1비트폭의 시간으로 세트
              MOVWF        TMR0                      ;타이머 재차 스타트
              DECFSZ        BITCNT,F                ;비트 카운터-1, 종료인가?
              GOTO           NEXTRXBIT             ;다음 데이터 수신으로
;*** 스톱비트 수신처리 ***
              BTFSS           PORTA,4                ;데이터 입력하고 스톱비트 확인?
              BSF               ERROR                   ;스톱비트가 아닐 때 에러
              BCF               INTCON,T0IE           ;인터럽트 금지
              BCF               RXBUSY                 ;수신중 플래그 리셋
              BCF               RECV                     ;데이터 수신 플래그 세트
;
;**** 인터럽트 병렬처리를 실행할 때는 여기에 수신 완료시의 처리를 ***
;       추가하고, 처리 실행후 인터럽트 처리로 돌아간다.
;             CALL             RECEIVEPROCESS
              GOTO            RESTORE

;**** 데이터 비트 수신처리 ***
NEXTRXBIT
              BCF               STATUS,C               ;데이터의 0, 1에 의해 RXREG
              BTFSC           PORTA,4                  ;에 0, 1을 세트한다
              BSF               STATUS,C                ;1 case
              RRF               RXREG,F                  ;set data to RXREG
              GOTO            RESTORE
;***** 10μs 지연 타이머 *****
TIME10                                                        ;10μs
              MOVLW         7H
              MOVWF         CNT2
T_LP2     DECFSZ         CNT2,F                     ;2+3*7-1=22
              GOTO            T_LP2
              RETURN                                         ;22+1=23

 

[email protected]
copyright : 1998 PROCHIPS TECHNOLOGY INC
Last Updated : 1998. 10. 22